PutEx (VBScript)

This code can be found in Chapter 21 of Active Directory, 3rd Edition

Purchase XP Cookbook or Networking Recipes for only $25 plus shipping! While supplies last.

Find out how to download all of the VBScript code from this site.

' From the book "Active Directory, Third Edition" 
' ISBN: 0-596-10173-2

Const ADS_PROPERTY_CLEAR = 1
Const ADS_PROPERTY_UPDATE = 2
Const ADS_PROPERTY_APPEND = 3
Const ADS_PROPERTY_DELETE = 4
   
Dim objUser  'An ADSI User object
Dim strPager 'A text string holding a phone number
   
Set objUser=GetObject("LDAP://cn=Administrator,cn=Users,dc=mycorp,dc=com")
   
'**********************************************************************
'Set three pager numbers for the Administrator account
'**********************************************************************
objUser.PutEx ADS_PROPERTY_UPDATE, "pager", _
  Array("123-1234", "234-2345", "345-3456") 
objUser.SetInfo
objUser.GetInfo
For Each strPager in objUser.telephonePager
  WScript.Echo strPager
Next
   
'**********************************************************************
'Delete the first and last number
'**********************************************************************
objUser.PutEx ADS_PROPERTY_DELETE, "pager", Array("123-1234", "345-3456")
objUser.SetInfo
objUser.GetInfo
For Each strPager in objUser.telephonePager
  WScript.Echo strPager
Next
   
'**********************************************************************
'Add a new pager number without deleting the remaining number
'**********************************************************************
objUser.PutEx ADS_PROPERTY_APPEND, "pager", Array("456-4567") 
objUser.SetInfo
objUser.GetInfo
For Each strPager in objUser.telephonePager
  WScript.Echo strPager
Next
   
'**********************************************************************
'Delete all values
'**********************************************************************
objUser.PutEx ADS_PROPERTY_CLEAR, "pager", vbNull
objUser.SetInfo
objUser.GetInfo
For Each strPager in objUser.telephonePager
  WScript.Echo strPager
Next

This code has been viewed 3846 times.

New from the creators of TechTasks.com: StatSheet.com