' This VBScript code deletes the specified application partition

' ---------------------------------------------------------------
' From the book "Active Directory Cookbook" by Robbie Allen
' ISBN: 0-596-00466-4
' ---------------------------------------------------------------

' ------ SCRIPT CONFIGURATION ------
strAppPart = "<AppPartitionDN>"  ' DN of the app partition to delete
' ------ END CONFIGURATION ---------

set objRootDSE = GetObject("LDAP://RootDSE")
strBase    =  "<LDAP://cn=Partitions," & objRootDSE.Get("ConfigurationNamingContext") & ">;"
strFilter  = "(&(objectclass=crossRef)(objectcategory=crossRef)(nCName=" & _
             strAppPart & "));" 
strAttrs   = "cn,distinguishedName;"
strScope   = "onelevel"

set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Open "Active Directory Provider"
set objRS = objConn.Execute(strBase & strFilter & strAttrs & strScope)

if objRS.RecordCount <> 1 then
   WScript.Echo "Did not find a match for " & strAppPart
else
   objRS.MoveLast
   set objAppPart = GetObject("LDAP://" & _
                              objRS.Fields("distinguishedName").Value )
   objAppPart.DeleteObject(0)
   Wscript.Echo "Deleted " & objRS.Fields("distinguishedName").Value
end if