Add user to group (ASP)

This code can be found in Chapter 28 of Active Directory, 3rd Edition

Purchase XP Cookbook or Networking Recipes for only $25 plus shipping! While supplies last.

Find out how to download all of the ASP code from this site.

<!--
' From the book "Active Directory, Third Edition" 
' ISBN: 0-596-10173-2
-->
<HTML>
<HEAD>
<TITLE>Adding Users to Groups from the default Users Container</TITLE>
   
</HEAD>
   
<BODY>
<%
  On Error Resume Next
  If Request.Form("Submit") <> "" Then
    strGroupPath = "LDAP://" & Request.Form("group") _
      & ",cn=Users,dc=mycorp,dc=com"
    strUserPath = "LDAP://" & Request.Form("user") _
      & ",cn=Users,dc=mycorp,dc=com"
   
    Set objNamespace = GetObject("LDAP: ")
    Err.Clear
    Set objGroup = objNamespace.OpenDSObject(strGroupPath, _
                    CStr(Request.Form("Name")), _
                    CStr(Request.Form("Password")),0)
    If Err=0 Then
      If objGroup.IsMember(strUserPath) Then
        Response.Write "User is already a member of the group"
      Else
        Err.Clear
        objGroup.Add(strUserPath)
        If Err=0 Then
          Response.Write "User is now a member of the group"
        Else
          Response.Write "An error occurred when adding the user to the group."
        End If
      End If
    Else
      Response.Write "Authentication failed."
    End If
  End If
%>
<P>
<FORM ACTION = "userlist2.asp" METHOD = "POST">
  <P>Users: 
  <SELECT NAME = "user">
<%  Set objUsersContainer = _
      GetObject("LDAP://cn=Users,dc=mycorp,dc=com")
    For Each objObject in objUsersContainer
      If objObject.Class = "user" Then %>
        <OPTION><% = objObject.Name %>
<%    End If
    Next %>
  </SELECT>
  Groups: 
  <SELECT NAME = "group">
<%  For Each objObject in objUsersContainer
      If objObject.Class = "group" Then %>
        <OPTION><% = objObject.Name %>
<%    End If
    Next %>
  </SELECT></P>
   
  <P>Username: <INPUT 
    NAME="Name"
    TYPE=TEXT
    VALUE="mycorp\administrator"
    SIZE="60">
   
  <P>Password<INPUT 
    TYPE="PASSWORD"
    NAME="Password">
   
  <P><INPUT TYPE=SUBMIT NAME="Submit" VALUE="Add User To Group!">
</FORM>
</BODY>
</HTML>

This code has been viewed 7100 times.

New from the creators of TechTasks.com: StatSheet.com