Listing12_Create_Link (VBScript)

This code can be found in Chapter 9 of Managing Enterprise Active Directory Services

Purchase XP Cookbook or Networking Recipes for only $25 plus shipping! While supplies last.

Find out how to download all of the VBScript code from this site.

'# From the book "Managing Enterprise Active Directory Services"
'# ISBN: 0-672-32125-4

Dim user, passwd, server, site1, site2, rep_interval, link_cost
Dim link_name, ipLinks_dn, ldapObj, ipLinksObj, linkObj
Dim sites_dn, site1_dn, site2_dn

' Link information
site1        = "RTP"
site2        =  "Default-First-Site-Name"
rep_interval = 30
link_cost    = 100

link_name  = site1 & "::" & site2
sites_dn   = "cn=sites,cn=configuration,dc=xyz,dc=com"
ipLinks_dn = "cn=IP,cn=Inter-Site Transports," & sites_dn

' Bind information
server = "dc1.xyz.com"
user   = "administrator@xyz.com"
passwd = "password"

Set ldapObj = GetObject("LDAP:")
Set ipLinksObj = ldapObj.OpenDsObject("LDAP://" & server & "/" & _
                                       ipLinks_dn, user, passwd, 1)
Wscript.Echo "Creating link " & link_name
Set linkObj = ipLinksObj.Create("siteLink","cn=" & link_name)
linkObj.Put "replinterval", rep_interval
linkObj.Put "cost", link_cost
site1_dn = "cn=" & site1 & "," & sites_dn
site2_dn = "cn=" & site2 & "," & sites_dn
linkObj.Put "sitelist", Array(site1_dn,site2_dn)
linkObj.SetInfo()
Wscript.Echo "Link creation complete"

This code has been viewed 710 times.

New from the creators of TechTasks.com: StatSheet.com